1С и Telegram. Об опыте использования прокси-серверов

Публикация № 879132

Разработка - Практика программирования

Прокси-сервер Телеграм Telegram

37
Рассказ о том, как немного улучшить отправку сообщений из 1С в Телеграм в условиях использования прокси-серверов

Все мы знаем и любим мессенджер Телеграм. Несмотря на то, что данный мессенджер заблокирован в России, многие пользуются им. Этот факт очевиден хотя бы потому, что на Инфостарте регулярно выходят статьи, освещающие какие-либо аспекты интеграции решений на платформе 1С и Телеграма. В данной статье хочу поделиться небольшим и, может быть, очевидным лайфхаком по использованию Телеграма в условиях блокировки.

ИнтернетПрокси = Новый ИнтернетПрокси(Ложь);
ИнтернетПрокси.Установить(Прокси.Протокол, Прокси.Сервер, Прокси.Порт, Прокси.Пользователь, Прокси.Пароль, Ложь);
Соединение  =  Новый HTTPСоединение("api.telegram.org",443,,,ИнтернетПрокси,,Новый ЗащищенноеСоединениеOpenSSL());
ПолучениеЗапрос = "bot"+ТокенБота+"/sendMessage?chat_id="+Адресат+"&text="+ Сообщение;
Запрос = Новый HTTPЗапрос(ПолучениеЗапрос);
Ответ = Соединение.Получить(Запрос);
  

После блокировки Телеграма и последовавших за этим событий возник резонный вопрос о стабильности работы мессенджера. Иными словами, в условиях, когда подключение к Телеграму осуществляется с использованием различных прокси, возникают дополнительные риски, связанные с тем, что прокси-сервер может быть заблокирован или перегружен. Здесь замечу, что мы решали задачу по отправке уведомлений о различных событиях системы в Телеграм. Ну например, кто-то из пользователей изменил какой-то документ, и об этом изменении информируются все остальные пользователи путем отправки сообщения в общий чат. Функциональность незатейливая, но позволяющая поддерживать распространение информации в условиях совместной работы.

В благодатные времена, когда Телеграм не блокировался, описанная выше функциональность реализовывалась буквально в несколько строк кода:

Соединение  =  Новый HTTPСоединение("api.telegram.org",443,,,,,Новый ЗащищенноеСоединениеOpenSSL());
ПолучениеЗапрос = "bot"+ТокенБота+"/sendMessage?chat_id="+Адресат+"&text="+ Сообщение;
Запрос = Новый HTTPЗапрос(ПолучениеЗапрос);
Ответ = Соединение.Получить(Запрос);

После блокировки приходится добавить прокси:

Казалось бы, код практически не усложнился. Но это на первый взгляд. А где взять прокси? Логично, что в Интернете есть множество сайтов, на которых приведены актуальные списки прокси-серверов. И в самом начале мы воспользовались одним из таких сайтов, где и взяли параметры для подключения к прокси-серверу. Естественно, что сами параметры подключения к прокси оставлять в исходном коде просто не спортивно, ведь может возникнуть и возникнет необходимость изменить их.  Поэтому вполне логично завести справочник прокси-серверов. Сам справочник приведен на рисунке ниже:

Нетрудно догадаться, что если прокси хранятся в справочнике, то на поверхности лежит идея о том, чтобы в случае недоступности прокси-сервера, через который производится отправка, использовать другой прокси-сервер из справочника

ВыборкаПрокси = Справочники.Прокси.Выбрать();
Пока ВыборкаПрокси.Следующий() Цикл

	Попытка
		ИнтернетПрокси = Новый ИнтернетПрокси(Ложь);
		ИнтернетПрокси.Установить(ВыборкаПрокси.Протокол, ВыборкаПрокси.Сервер, ВыборкаПрокси.Порт, ВыборкаПрокси.Пользователь, ВыборкаПрокси.Пароль, Ложь);
		Соединение  =  Новый HTTPСоединение("api.telegram.org",443,,,ИнтернетПрокси,,Новый ЗащищенноеСоединениеOpenSSL());
		ПолучениеЗапрос = "bot"+ТокенБота+"/sendMessage?chat_id="+Адресат+"&text="+ Сообщение;
		Запрос = Новый HTTPЗапрос(ПолучениеЗапрос);
		Ответ = Соединение.Получить(Запрос);					
		Прервать;
	Исключение
	КонецПопытки;	
КонецЦикла;

Примерно такая версия отправки сообщений через прокси начала работать у нас в апреле через несколько дней после  известных всем событий. Пару недель этот способ работал хорошо, но потом возникли некоторые проблемы:

  • Часть прокси-серверов оказалась заблокированной
  • Другая часть прокси периодически становилась недоступной

Для решения этих проблем в справочнике были введены реквизиты "ИспользоватьПоУмолчанию" и "Порядок", которые были призваны обеспечить попытку отправки сообщений через наиболее надежные прокси-сервера. Очевидно, что надежность определялась на глазок. Кроме того изменять эти реквизиты приходилось вручную, что не особо радовало.

На этом велосипеде мы ехали около месяца. Но в начале июня стало понятно, что кактус уже слишком колючий, чтобы его есть, поскольку время отправки сообщений варьировалось от 5 до 30 минут. Иными словами, перебор прокси шел в соответствии с вручную установленными параметрами и, если везло, то отправка происходила с первого-второго раза, а если нет, то перебор прокси продолжался, при этом, как было замечено выше, перебор этот не был основан на сколь-нибудь объективной оценке. Здесь замечу, что при всех описанных неудобствах сообщения все-таки приходили, однако ценность пришедшего через пол часа сообщения, мягко говоря, не всегда была велика, а иногда возникала путаница: поскольку отправка сообщений осуществлялась через фоновые задания, то иногда отправленное позже сообщений приходило даже раньше более раннего сообщения. Ничего хорошего в такой ситуации нет.

Что же делать? С одной стороны можно было забросить Телеграм и переехать на Slack или Viber или даже вернуться к использованию собственного XMPP-сервера. С другой стороны не хотелось отказываться от всех наработок, да и трудозатраты на переезд представлялись вполне ощутимыми. В связи с этим в голову пришла простая и логичная мысль - вести историю отправки и уже на основании этой истории строить своеобразный  рейтинг прокси-серверов. Такой подход позволил бы автоматически определять прокси, который в настоящее время наиболее надежен (то есть стабильно отправляет сообщения).

Для ведения истории был создан простой регистр:

В этот регистр записывался факт отправки или неотправки сообщения через прокси-сервер,  если сообщение было отправлено, то записывалась 1, иначе -1.

Таким образом, код отправки стал выглядеть примерно так:

Функция ПолучитьHTTPСоединениеСПрокси(Прокси) Экспорт
	Если Прокси = Неопределено Тогда
		Соединение  =  Новый HTTPСоединение("api.telegram.org",443,,,,,Новый ЗащищенноеСоединениеOpenSSL());
	Иначе
		ИнтернетПрокси = Новый ИнтернетПрокси(Ложь);
		ИнтернетПрокси.Установить(Прокси.Протокол, Прокси.Сервер, Прокси.Порт, Прокси.Пользователь, Прокси.Пароль, Ложь);
		Соединение  =  Новый HTTPСоединение("api.telegram.org",443,,,ИнтернетПрокси,,Новый ЗащищенноеСоединениеOpenSSL());
	КонецЕсли;
	Возврат Соединение;
КонецФункции

Процедура ДобавитьВНаборСтатистикиОтправкиСообщенийВМессенджер(Набор, Прокси, Отправлено)
	НСтр = Набор.Добавить();
	НСтр.Период = ТекущаяДата();
	НСтр.Прокси = Прокси;
	НСтр.Отправлено = Отправлено;
КонецПроцедуры

Функция ОтправитьСообщение(Сообщение, Адресат, ТокенБота)  Экспорт
		
	ВыборкаПрокси = ПолучитьАктивныеПрокси();
	Ответ = Неопределено;
	Ок = "";
	
	Набор = РегистрыСведений.СтатистикаОтправкиСообщенийВМессенджер.СоздатьНаборЗаписей();
	
	Пока ВыборкаПрокси.Следующий() Цикл

		Попытка
			Соединение  =  ПолучитьHTTPСоединениеСПрокси(ВыборкаПрокси.Ссылка);
			ПолучениеЗапрос = "bot"+ТокенБота+"/sendMessage?chat_id="+Адресат+"&text="+ Сообщение;
			Запрос = Новый HTTPЗапрос(ПолучениеЗапрос);
			Ответ = Соединение.Получить(Запрос);
			ДобавитьВНаборСтатистикиОтправкиСообщенийВМессенджер(Набор, ВыборкаПрокси.Ссылка, 1);
						
			Прервать;
		Исключение
			ДобавитьВНаборСтатистикиОтправкиСообщенийВМессенджер(Набор, ВыборкаПрокси.Ссылка, -1);
		КонецПопытки;
	
	КонецЦикла;
	
	Набор.Записать(Ложь);
		
	Если ЗначениеЗаполнено(Ответ) = Истина Тогда
		
		Чтение = Новый ЧтениеJSON;
		Чтение.УстановитьСтроку(Ответ.ПолучитьТелоКакСтроку());		
		ОтветСоотв = ПрочитатьJSON(Чтение,Истина);
		Ок = ОтветСоотв["ok"] ;	
		
	КонецЕсли;
	
	Возврат Ок
	
КонецФункции

В приведенном фрагменте кода присутствует вызов функции ПолучитьАктивныеПрокси(), однако нет ее объявления. Поэтому хочется остановиться на данной функции подробнее. Само по себе хранение истории отправки сообщений дает совсем не много. Ну что интересного в, например, таких данных:

Видно, что через какие-то прокси сообщения не уходят, через какие-то уходят, а иногда отправка работает через раз. Очевидно, что необходим какой-то критерий для составления того самого рейтинга прокси, о котором говорилось выше. Долго думать над таким критерием не пришлось - за аналог был взят метод оценки по трем точкам. То есть прокси ранжировались исходя из суммы трех показателей:

  • сумма успешных и неуспешных отправлений за месяц;
  • успешность последней отправки;
  • сумма успешных и неуспешных отправлений за текущий день

Каждый из указанных показателей имеет свой коэффициент - 7/12, 3/12 и 2/12 соответственно, коэффициенты подобраны эвристически. При этом неуспешное отправление при суммировании за день засчитывается не за -1 а за -0,8. Такую оценку словами можно описать примерно так: "если прокси хорошо отправлял в течении предыдущего месяца (читай 30 предшествующих дней, то скорее всего будет выбран он, однако если в течении дня прокси работал нестабильно и последняя отправка была неудачной, то возможно его рейтинг снизится) ". Теперь приведу код ранжирования:

Функция ПолучитьАктивныеПрокси() Экспорт
	Запрос = Новый Запрос;            
	Запрос.Текст = "ВЫБРАТЬ
	               |	СтатистикаОтправкиСообщенийВМессенджерСрезПоследних.Прокси,
	               |	СтатистикаОтправкиСообщенийВМессенджерСрезПоследних.Отправлено
	               |ПОМЕСТИТЬ ВтПоследние
	               |ИЗ
	               |	РегистрСведений.СтатистикаОтправкиСообщенийВМессенджер.СрезПоследних КАК СтатистикаОтправкиСообщенийВМессенджерСрезПоследних
	               |ГДЕ
	               |	СтатистикаОтправкиСообщенийВМессенджерСрезПоследних.Отправлено = 1
	               |;
	               |
	               |////////////////////////////////////////////////////////////////////////////////
	               |ВЫБРАТЬ
	               |	СтатистикаОтправкиСообщенийВМессенджер.Прокси,
	               |	СУММА(ВЫБОР
	               |			КОГДА СтатистикаОтправкиСообщенийВМессенджер.Отправлено < 0
	               |				ТОГДА -0.8
	               |			ИНАЧЕ СтатистикаОтправкиСообщенийВМессенджер.Отправлено
	               |		КОНЕЦ) КАК Отправлено
	               |ПОМЕСТИТЬ ВтДень
	               |ИЗ
	               |	РегистрСведений.СтатистикаОтправкиСообщенийВМессенджер КАК СтатистикаОтправкиСообщенийВМессенджер
	               |ГДЕ
	               |	СтатистикаОтправкиСообщенийВМессенджер.Период МЕЖДУ &ДатаНачала И &ДатаКонец
	               |
	               |СГРУППИРОВАТЬ ПО
	               |	СтатистикаОтправкиСообщенийВМессенджер.Прокси
	               |;
	               |
	               |////////////////////////////////////////////////////////////////////////////////
	               |ВЫБРАТЬ
	               |	СтатистикаОтправкиСообщенийВМессенджер.Прокси,
	               |	СУММА(СтатистикаОтправкиСообщенийВМессенджер.Отправлено) КАК Отправлено
	               |ПОМЕСТИТЬ ВтМесяц
	               |ИЗ
	               |	РегистрСведений.СтатистикаОтправкиСообщенийВМессенджер КАК СтатистикаОтправкиСообщенийВМессенджер
	               |ГДЕ
	               |	СтатистикаОтправкиСообщенийВМессенджер.Период МЕЖДУ &ДатаНачала1 И &ДатаКонец1
	               |
	               |СГРУППИРОВАТЬ ПО
	               |	СтатистикаОтправкиСообщенийВМессенджер.Прокси
	               |;
	               |
	               |////////////////////////////////////////////////////////////////////////////////
	               |ВЫБРАТЬ
	               |	ВтМесяц.Прокси,
	               |	ВтМесяц.Отправлено КАК ОтправленоМесяц,
	               |	ВтПоследние.Отправлено КАК ОтправленоПоследнее,
	               |	ВтДень.Отправлено КАК ОтправленоДень,
	               |	ЕСТЬNULL(ВтМесяц.Отправлено, 0) * (7 / 12) + ЕСТЬNULL(ВтПоследние.Отправлено, 0) * (3 / 12) + ЕСТЬNULL(ВтДень.Отправлено, 0) * (2 / 12) КАК ОтправленоУсред
	               |ПОМЕСТИТЬ ВтСтат
	               |ИЗ
	               |	ВтМесяц КАК ВтМесяц
	               |		ЛЕВОЕ СОЕДИНЕНИЕ ВтПоследние КАК ВтПоследние
	               |		ПО ВтМесяц.Прокси = ВтПоследние.Прокси
	               |		ЛЕВОЕ СОЕДИНЕНИЕ ВтДень КАК ВтДень
	               |		ПО ВтМесяц.Прокси = ВтДень.Прокси
	               |;
	               |
	               |////////////////////////////////////////////////////////////////////////////////
	               |ВЫБРАТЬ
	               |	ЕСТЬNULL(ВтСтат.ОтправленоУсред, 0) КАК ОтправленоУсред,
	               |	ВложенныйЗапрос.Ссылка КАК Ссылка
	               |ИЗ
	               |	(ВЫБРАТЬ
	               |		Прокси.Ссылка КАК Ссылка,
	               |		Прокси.Порядок КАК Порядок
	               |	ИЗ
	               |		Справочник.Прокси КАК Прокси
	               |	ГДЕ
	               |		Прокси.Активно = ИСТИНА) КАК ВложенныйЗапрос
	               |		ЛЕВОЕ СОЕДИНЕНИЕ ВтСтат КАК ВтСтат
	               |		ПО ВложенныйЗапрос.Ссылка = ВтСтат.Прокси
	               |
	               |УПОРЯДОЧИТЬ ПО
	               |	ОтправленоУсред УБЫВ";
				   
	Запрос.УстановитьПараметр("ДатаНачала", НачалоДня(ТекущаяДата()) );
	Запрос.УстановитьПараметр("ДатаКонец", ТекущаяДата());
	Запрос.УстановитьПараметр("ДатаНачала1", ДобавитьМесяц(ТекущаяДата(), -1));
	Запрос.УстановитьПараметр("ДатаКонец1", ТекущаяДата());	
	
	Результат = Запрос.Выполнить();
	Выборка = Результат.Выбрать();
	
	Возврат Выборка;
	
КонецФункции

Функция оказалась совсем незатейливой.  Однако результаты выбранного подхода порадовали. В течении недели собиралась статистика и время отправки сообщений так и оставалось на уровне 5-30 минут, перебор прокси все еще был почти случайным. Но через несколько дней время отправки стабилизировалось и в среднем перестало превышать 1 минуту с редкими задержками до 5 минут.  Казалось бы, просто на основании истории были определены 1-2 наиболее стабильных прокси сервера, которые и обеспечивали стабильную отправку сообщений. Однако на деле происходит так, что если эти стабильные прокси вдруг почему-то перестают работать, то их заменяют другие прокси-сервера, которые может быть, не так стабильны, но в текущий момент работают. При этом, например, на следующий день отправка может пойти снова через тот прокси, который вчера почему-то "захандрил".

Для подтверждения сказанного приведу простенькую статистику.

Из рисунка видно, что в период с 16 по 22 июня количество ошибок (когда прокси не отвечал) при отправке сообщений было крайне велико. При этом каждая ошибка увеличивала время отправки сообщений. Однако позднее количество ошибок при отправке снижается и выходит на достаточно стабильный уровень, что обусловлено, как уже говорилось выше, с одной стороны отсутствием необоснованного перебора прокси-серверов и с другой стороны возможностью автоматически производить отправку через прокси с "рейтингом чуть ниже", если "самый хороший сервер" почему-то не отвечает.

Например, заметно, что в первый день использования истории и ранжирования перебор прокси производился практически случайно и большое количество ошибок при отправке обуславливалось тем, что происходило подключение к недоступным прокси. Замечу только, что многие из этих недоступных прокси серверов проверялись буквально за день до этого и были вполне работоспособны.

Если же посмотреть на свежие данные, то очевидно, что:

  • При небольшом числе сообщений за день отправка происходит с использованием одного-двух прокси-"лидеров рейтинга" (например 31.07.2018, 01.08.2018);
  • При чуть большем количестве сообщений иногда используются прокси с чуть меньшим рейтингом (например 30.07.2018);
  • При еще большем количестве сообщений и наличии проблем у прокси-"лидеров" используется еще большее количество серверов (например 27.07.2018), но при этом в отличии от ситуации на предыдущем рисунке ( 16.06.2018) доля обращений к серверам, которые не отвечают, совсем мала; если говорить по-другому то аутсайдеру давался шанс, в условиях, когда лидеры рейтинга сплоховали, но если шанс использован не был, то второго шанса точно не будет.

В завершении хочу сказать, что приведенное решение в общем-то лежит на поверхности. Однако надеюсь, что кому-то этот опыт будет полезен, поскольку он наглядно демонстрирует то, что даже в условиях блокировки и не всегда стабильной работы прокси не стоит спешить отказываться от уже реализованной интеграции с Телеграмом.

Этой мой первый пост, буду признателен за конструктивную обратную связь!

37

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. user634257_mryzhov 02.08.18 11:17 Сейчас в теме
Решение красивое.
Не решились использовать в продакшене стороние прокси серверы - в плане безопасности сомнительное решение
Переход на slack оказался проще и логичнее.
4. saa@kuzov.org 02.08.18 13:15 Сейчас в теме
(1)
slack


Поделитесь, пожалуйста, подробностями?
1) Есть ли апи в бесплатной версии?
2) Если платная, то как платите с расчетного счета?
3) Встречали ли примеры интеграции с 1С в открытом доступе?
8. user634257_mryzhov 02.08.18 13:51 Сейчас в теме
(4)
1. Есть, все бесплатно
3. Интеграция
	ssl = Новый ЗащищенноеСоединениеOpenSSL(неопределено,Новый СертификатыУдостоверяющихЦентровWindows()); 
	ЗаголовкиHTTP=Новый Соответствие();		
	ЗаголовкиHTTP.Вставить("Content-Type","Content-Type: application/json");
	HTTPСоединение = Новый HTTPСоединение("hooks.slack.com",443,,,,,ssl,);  
	HTTPЗапрос = Новый HTTPЗапрос(webhook) ; 
	ТелоЗапроса="{""text"": """+text+"""}";
	HTTPЗапрос.УстановитьТелоИзСтроки(ТелоЗапроса,КодировкаТекста.UTF8,ИспользованиеByteOrderMark.НеИспользовать);
HTTPОтвет=HTTPСоединение.ОтправитьДляОбработки(HTTPЗапрос);

Показать

webhook - токен из слака
text - текст сообщения
9. Infactum 283 02.08.18 14:19 Сейчас в теме
(8) JSON через конкатенацию строк, без экранирования. Норм интеграция.
PLAstic; JohnyDeath; CSiER; +3 Ответить
20. Yashazz 2905 07.08.18 12:10 Сейчас в теме
(9) Ну ладно ворчать-то. Ну бывает. Все мы порой не брезгуем хмл или джейсон как строку колбасить, иногда это очевидно проще)
2. sound 529 02.08.18 11:43 Сейчас в теме
Хороший первый пост. С почином :)
12. altmf 38 02.08.18 15:22 Сейчас в теме
3. Infactum 283 02.08.18 11:45 Сейчас в теме
Свой прокси сервер не стоит практически ничего даже для физлиц. А ещё более правильно было бы настроить прозрачную маршрутизацию на роутере. Любит народ костыли городить
5. saa@kuzov.org 02.08.18 13:20 Сейчас в теме
(3) Дроплет на DO от 5 баксов в месяц. Дальше настроить не проблема.
Проблема только в том, что с расчетного счета компании не оплатить никак.

А что значит "настроить прозрачную маршрутизацию на роутере"? Куда кого маршрутизировать?
У меня телеграмм на компе и на мобилке.
На мобилке я ничего маршрутизировать не могу. Могу VPN настроить. Но тогда обязательной становится блокировка экрана паролем, а это неудобно.

Поделитесь, пожалуйста, мудростью. Можно даже в личку. Спасибо!
6. Infactum 283 02.08.18 13:35 Сейчас в теме
(5) Поднять VPN на роутере. Трафик на нужные подсети/адреса заворачивать туда.
Довольно очевидное решение. Любой админ настроит легко.

Ну и 5$ за DO это перебор, если требуется только к api телеграма доступ получить.
10. altmf 38 02.08.18 15:14 Сейчас в теме
(3) Свой прокси-сервер, безусловно, тоже является решением. Однако не могу не поинтересоваться, а в чем же описанное мной решение является костылем с точки зрения практики программирования? Статья ведь в этой рубрике размещена =)
13. Infactum 283 02.08.18 15:28 Сейчас в теме
(10) Если речь идет о коде ради кода - то сойдет.
Но программист (не просто кодер!) должен сначала обдумать варианты решения и выбрать оптимальный. Потом уже писать что-то.
14. altmf 38 02.08.18 15:51 Сейчас в теме
(13)Строго говоря с точки зрения программиста в статье описаны некоторые варианты решения и приведена мотивация, почему они не использованы. Выбор же того, выполнять доработку программного обеспечения, настройку сетевого оборудования или настраивать собственный прокси, лежит несколько за пределами компетенций и трудовых функций программиста. Поэтому не могу согласиться с вами ни в вашей оценке ни в ее форме. Кроме того, предложенный вами вариант точно также несет определенные риски и обладает определенными особенностями. Так что считаю, что разнообразие всегда на пользу и, что очевидно, одна задача может быть решена разными способами тем более в разных условиях.
7. 🅵🅾️🆇 02.08.18 13:40 Сейчас в теме
А в чем проблема купить на aruba.it VPS сервер за 1$/мес и спокойно использовать его как прокси самому, раздать друзьям и попутно еще и всякие свои проектики на нем вести? Веб сервер поднять, опять же.

Вот что по ресурсам и нагрузке на чуть более дорогом хостинге в нидерландах (каком - не скажу).
На нем поднят веб-сервер, openvpn и сидит около 30 людей с проксей.
Прикрепленные файлы:
11. altmf 38 02.08.18 15:19 Сейчас в теме
(7) Да в общем-то такой проблемы и нет, но как я уже заметил выше в статье раскрывается аспект повышения надежности использования прокси с точки зрения программирования и программиста, потому и размещена статья в соответствующей рубрике.
Ну и если говорить о собственном прокси, то нельзя ведь не заметить, что и он наверняка может подпасть под блокировку или стать неприемлемо медленным. Или вы по каким-то другим причинам не делитесь с нами тем самым хостингом в Нидерландах? =)
15. 🅵🅾️🆇 02.08.18 17:51 Сейчас в теме
(11) Не хочу чтоб подумали, что рекламирую.
Хостинг как хостинг, я про него вообще не слышал, за 230 руб/мес то что вы видите на скриншоте.
Если есть интерес или вопросы по поднятию - в личку.

Аруба показала себя довольно вменяемо, разворачивают долго (пол дня надо ждать) и интерфейс админки супер отвратительный и запутанный.
Но собственно как подключитесь putty - Вам уже, по идее, все равно. Чешский лагал, кстати, а итальянский и остальные (по отзывам) себя хорошо показывали за такую цену. Трафика там - 2 ТБ/мес, если не ошибаюсь.

Ну это я к тому, что слишком много ухищрений, чтоб сэкономить 1$/мес. Дополнительным бонусом сможете сами сидеть и друзьям в пользование отдать.
Заблокируют - да боже, сменю хостинг. Заблокируют весь интернет - смысл пребывания в этой стране из близкого к нулю - станет отрицательным и сменю не хостинг, а страну.


PS: а, черт с ним, вот адрес моих проксей: http://185.246.152.100/ (через who is сами найдете)
PPS: если что, свои прокся можно скидывать юзверам в таком виде: https://t.me/socks?server=YOUR_IP&port=YOUR_PORT&user=YOUR_LOGIN&pass=YOUR_PASS­WORD (по клику они автоматически подключатся в телеге)
mirco; comol; altmf; CSiER; +4 Ответить
16. altmf 38 03.08.18 04:18 Сейчас в теме
(15)Информация о хостингах интересная =)
17. PLAstic 219 06.08.18 10:18 Сейчас в теме
Фразы, подразумевающие гениальность идеи несколько раз встречаются в тексте статьи.
Давай разовьём её реальную полезность...

1) Почему доступность прокси определяется на боевой отправке? Зачем вы попусту тратите время доставки боевых сообщений?
Делаете фоновое задание, которое будет пробегаться по списку прокси и служебному пользователю слать сообщение. Так вы будете получать картину рабочих проксей на текущий момент в фоновом режиме.
2) Я бы добавил в алгоритм время следующего опроса прокси. Т.е. если у вас стабильно работал прокси, а потом не отвечает на запрос раз, второй, третий, то с каждым отлупом в непрерывной серии отлупов увеличивать время следующей проверки этого прокси, до максимум суток (например).

Ну и вообще, я бы рекомендовал не париться с проксями, а арендовать за 1200 руб/мес виртуалку в одной из западных республик, повесить на неё вебхук и наслаждаться моментальным общением с ботами.
CyberCerber; sound; altmf; +3 Ответить
18. altmf 38 06.08.18 10:52 Сейчас в теме
(17)
Фразы, подразумевающие гениальность идеи несколько раз встречаются в тексте статьи.

О гениальности речи нет, но если у вас есть предложения по приданию статье более сдержанной, на ваш взгляд, стилистики, то готов обсудить их в личке.
1. Я согласен с вами, что доступность прокси можно и нужно определять отдельно и пользоваться этой информацией. Однако в условиях когда в день таких сообщений отправляется в среднем несколько десятков (хотя исключения бывают, но касаются они технологических операций), а также потенциальная задержка в несколько минут устраивала, описанный выше способ отправки был признан приемлемым и мы переключились на другие задачи
2. Это тоже интересная идея, но как я сказал выше, устроил даже весьма топорный вариант.
19. pablo_escobar 06.08.18 19:29 Сейчас в теме
Попробовал общаться с ботом через прокси(нашел бесплатный попробовать), не работает пишет
Ошибка работы с Интернет: Ошибка инициализации SSL-соединения
, такую же ошибку выдает если без прокси пробовать, то есть блокирует провайдер. Включил впн все работает с этим прокси, да и через приложение на телефоне с ним работает. Прокси должен обладать какими то характеристиками чтобы провайдер не блокировал запросы? Пробовал на этом
ИнтернетПрокси.Установить("https", "socks5://93.88.75.208", 1080, , , Ложь);
21. Vainemeinen 79 08.08.18 16:05 Сейчас в теме
После блокировки Телеграма тоже написал подобную прослойку с отправкой через прокси, с той лишь разницей, что использовался не справочник, а регистр сведений, адреса проксей с socks5 загружал из открытых источников, и банил в регистре сведений, те адреса, через которые соединиться не получалось.
Так вот, в первую неделю все было замечательно, но потом абсолютно все свободные прокси оказались в бане - похоже РКН также пасет все свободные прокси и прикрывает их.
22. altmf 38 09.08.18 06:58 Сейчас в теме
(21)По поводу бана прокси-серверов РКН я, если честно, ожидал, что прокси будут баниться с завидным постоянством, однако нет, большая часть прокси, используемых в июне,жива до сих пор. Возможно это связано с тем, что к тому моменту активность РКН несколько снизилась.
23. uno-c 106 21.08.18 17:50 Сейчас в теме
Можно использовать Tor-browser. Ставите тор-браузер, запускаете - и в системе появляется локальный socks5 прокси, использующий сеть тор. Работает хорошо.
24. 🅵🅾️🆇 437 28.08.19 11:00 Сейчас в теме
Просто оставлю это тут
https://gist.github.com/PlugFox/5f62e43c56941e4c5a244de2422ee7f8

Пример отправки сообщений и файлов в телеграм (даже без задействования жесткого диска)
25. Diversus 2035 30.10.19 17:59 Сейчас в теме
Спасибо за труд, но мне кажется есть проблема с тем, что:
1. Регистр сведений СтатистикаОтправкиСообщенийВМессенджер имеет периодичность Секунда и если будет несколько запросов на отправку в секунду, то запись помещаться никуда не будет.
2. Нет преобразования GET-параметра text в формат URL.
26. Diversus 2035 15.11.19 19:03 Сейчас в теме
(0) Есть еще один тонкий момент. Есть два типа прокси SOCK5 и HTTPS. И в зависимости от типа прокси нужны разные варианты указания строки подключения. Причем в вашем случае вы по коду используете ТОЛЬКО HTTPS-прокси.
Вот мой вариант функции ПолучитьHTTPСоединениеСПрокси:
Функция ПолучитьHTTPСоединениеСПрокси(АдресСервера, Порт, Прокси) Экспорт
	
	Таймаут = Константы.TelegramTimeoutПодключений.Получить();
	Если Таймаут = 0 Тогда
		Таймаут = 30;
	КонецЕсли;
	
	Если Прокси = Неопределено Тогда
		Соединение = Новый HTTPСоединение(АдресСервера, Порт,,,,Таймаут,
			Новый ЗащищенноеСоединениеOpenSSL());
	Иначе
		ИнтернетПрокси = Новый ИнтернетПрокси(Ложь);
        
        АдресПрокси = СокрЛП(Прокси.Сервер);
		Если Прокси.Протокол = Перечисления.TelegramПроксиПротоколы.SOCKS5 Тогда
			АдресПрокси = "socks5://" + АдресПрокси;
		КонецЕсли;
		ИнтернетПрокси.Установить("https", АдресПрокси, Прокси.Порт, 
			СокрЛП(Прокси.Пользователь), СокрЛП(Прокси.Пароль), Ложь);
			
		Соединение  =  Новый HTTPСоединение(АдресСервера, Порт,,,ИнтернетПрокси,Таймаут,
			Новый ЗащищенноеСоединениеOpenSSL());
	КонецЕсли;
	
	Возврат Соединение;
	
КонецФункции
Показать

Я думаю по коду примерно понятно что к чему.
Оставьте свое сообщение

См. также

Полезные процедуры и функции для программиста 160

Статья Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) Практика программирования Универсальные функции

Все мы пишем программный код и часто используем процедуры, облегчающие его написание. Ниже приведена выборка таких полезных процедур и функций.

07.10.2019    11489    HostHost    23       

Перенос документов, остатков и справочников КА 1.1 => КА 2 / УТ 11. Обновлено до КА 2.4.10.х и УТ 11.4.10.х! Промо

Более 130 компаний выполнили переход на КА 2 или УТ 11 с помощью нашей разработки! Позволяет перенести не только остатки и справочники (как типовая обработка), но и документы за нужный период времени. Предоставляем техподдержку, оперативно исправляем замечания, выпускаем обновления при выходе новых релизов программ 1С. Вы можете проверить разработку до покупки: сделаем бесплатный тестовый перенос из вашей базы КА 1.1 и предоставим доступ к базе-результату через веб-клиент!

29700 руб.

Вебхук. Путь Телеграма 64

Статья Программист Конфигурация (md, cf) v8 Абонемент ($m) Внешние источники данных Интеграция

Долгое (на самом деле нет) и нелегкое путешествие телеграма к неведомым (из за РКН) конфигурациям 1С. Памятка себе.

1 стартмани

03.10.2019    5779    5    platonov.e    10       

Перенос данных УПП 1.3 => ERP 2 (ЕРП) / УТ 11 / КА 2.х (обработка переноса документов, остатков и справочников из "1С:Управление производственным предприятием, ред. 1.3" в ERP / УТ 11 / КА 2). Обновлен до УПП 1.3.127.х, КА 2.4.10.х и ERP 2.4.10.х! Промо

Обработка позволяет переносить из УПП 1.3 в ERP 2 документы за выбранный период и остатки. Типовая обработка от фирмы 1С документы не переносит. Также исправлены ошибки типовой обработки. При выходе новых релизов обновление высылается бесплатно в течение года. Разработка будет полезна фирмам-франчайзи, которые периодически выполняют такой перенос данных для заказчиков. Вы можете один раз приобрести обработку переноса, и потом бесплатно получать обновления при выходе новых релизов конфигураций 1С.

29700 руб.

Агрегатные функции СКД, о которых мало кто знает 353

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Пользуетесь ли Вы всеми возможными агрегатными функциями, которые предоставляет система компоновки данных? Если Вы используете только: СУММА, КОЛИЧЕСТВО, МИНИМУМ, МАКСИМУМ, СРЕДНЕЕ, то эта статья для Вас.

05.09.2019    15392    ids79    44       

Cashback 35% при покупке 1С лицензий на счет INFOSTART.RU с 27.11 по 04.12 Промо

Оформляете заказ на 1С лицензии или конфигурации. Получаете 35% от стоимости на счет в профиле INFOSTART.RU. Выбираете сервисы и продукты на сумму кэшбэка.

Три костыля. Сказ про фокусы в коде 124

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Три интересных (или странных) костыля в коде, которые могут помочь в повседневных и не очень задачах.

03.09.2019    10446    YPermitin    69       

Отслеживание выполнения фонового задания 143

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Универсальные функции Разработка

Запуск фонового задания из модуля внешней обработки. Отслеживание выполнения задания в виде прогресса, расположенного на форме.

17.08.2019    12574    ids79    16       

Перенос документов и справочников ERP 2 / КА 2 / УТ 11 => БП 3.0 Промо

Перенос позволяет настроить собственный обмен данными между указанными программами, альтернативный предлагаемому фирмой 1С. Предоставляем техподдержку по всем вопросам данного обмена. Можем подключиться к вам удаленно для разбора ситуаций. Оперативно обновляем при выходе новых релизов 1С. Бесплатные обновления в течение полугода.

19700 руб.

Функции СКД: ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив 261

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Подробное описание и использование внутренних функций системы компоновки данных: Вычислить, ВычислитьВыражение, ВычислитьВыражениеСГруппировкойМассив, ВычислитьВыражениеСГруппировкойТаблицаЗначений.

08.08.2019    17767    ids79    31       

Фоновое выполнение кода в 1С - это просто 124

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Как легко запускать выполнение в фоне, не прибегая к долгому описанию фоновых процедур.

02.08.2019    12676    avalakh    21       

Перенос данных КА 1.1 => ERP 2 (ЕРП) (обработка переноса документов, остатков и справочной информации из "1С:Комплексная автоматизация, ред. 1.1" в "1С:ERP Управление предприятием, ред 2"). Обновлен до КА 1.1.115.х и ERP 2.4.10.х Промо

Обработка позволяет переносить из КА 1.1 в ERP 2 документы за выбранный период и остатки. Типовая обработка от фирмы 1С документы не переносит. Также исправлены ошибки типовой обработки. При выходе новых релизов обновление высылается бесплатно в течение года. Разработка будет полезна фирмам-франчайзи, которые периодически выполняют такой перенос данных для заказчиков. Вы можете один раз приобрести обработку переноса, и потом бесплатно получать обновления в случае выхода новых релизов конфигураций 1С.

29700 руб.

СКД - наборы данных и связи между ними, создание собственной иерархии, вложенные отчеты 141

Статья Программист Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования

Набор данных объект. Использование в схеме компоновки нескольких наборов данных. Различные варианты связи наборов: объединение, соединение. Использование иерархии в отчетах на СКД. Создание собственной иерархии, иерархия детальных записей. Использование вложенных схем в отчетах на СКД.

26.07.2019    15920    ids79    8       

Перенос данных УТ 10.3 => УТ 11 / КА 2 / ERP 2 (ЕРП 2) (документы, остатки и справочная информация из "1С:Управление торговлей, ред. 10.3" в УТ 11 / КА 2 / ERP 2). Обновлен до УТ 10.3.56.х, УТ 11.4.10.х, КА 2.4.10.х и ERP 2.4.10.х! Промо

Уже более 100 компаний приобрели перенос и выполнили переход на УТ 11 / КА 2 / ERP 2 с помощью нашей разработки! Обработка перехода с УТ 10.3 на УТ 11 / КА 2 / ERP 2 позволяет перенести не только остатки на указанную дату (как типовой перенос), но и все возможные документы за выбранный период. При выходе новых релизов этих программ оперативно выпускаем обновление обработки. Предоставляем техническую поддержку. Можем сделать бесплатный тестовый перенос!

29700 руб.

СКД - использование расширений языка запросов, секция ХАРАКТЕРИСТИКИ 155

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Инструментарий разработчика Практика программирования

Автоматическое и не автоматическое заполнение полей компоновки данных. Использование расширений языка запросов для СКД «{…}», секция ВЫБРАТЬ, секция ГДЕ, параметры виртуальных таблиц. Автоматизированное использование дополнительных данных в запросе: секция ХАРАКТЕРИСТИКИ.

17.07.2019    13486    ids79    27       

Регистры сведений. За кулисами 129

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Небольшие заметки по внутреннему устройству регистров сведений.

09.07.2019    10519    YPermitin    12       

Подборка программ для взаимодействия с ЕГАИС Промо

ЕГАИС (Единая государственная автоматизированная информационная система) - автоматизированная система, предназначенная для государственного контроля за объёмом производства и оборота этилового спирта, алкогольной и спиртосодержащей продукции. Инфостарт рекомендует подборку проверенных решений для взаимодействия с системой.

"Меньше копипаста!", или как Вася универсальную процедуру писал 183

Статья Программист Стажер Нет файла v8 v8::СКД 1cv8.cf Бесплатно (free) Практика программирования Разработка

Программист Вася разбирает подход создания универсальных методов на примере программного вывода СКД.

04.07.2019    9292    SeiOkami    49       

Создание отчетов с помощью СКД - основные понятия и элементы 216

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Математика и алгоритмы

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    23604    ids79    17       

Очный семинар по регулярному менеджменту Александра Фридмана "Вы или Хаос", 12 декабря 2019 г. , Санкт-Петербург Промо

Семинар по регулярному менеджменту от Александра Фридмана для собственников, первых лиц и топов. Технология управленческого планирования, комплексного управления временем и другими ресурсами, выполнением поручений, делами, информацией, контактами (встречи-звонки-почта).

от 11000 до 29000 рублей

Многопоточное ускорение однопользовательских нагрузок в 1С + Microsoft SQL Server 2017 179

Статья Программист Нет файла v8 v8::Запросы Бесплатно (free) Практика программирования Разработка

Взаимодействие с Microsoft SQL Server нередко вызывает трудности у 1С-ников, а потому интересны любые моменты, связанные с его использованием. О своем опыте работы с новым SQL Server 2017 участникам конференции Infostart-2018 рассказал директор ООО «Аналитика софт» Дмитрий Дудин.

11.06.2019    13564    dmurk    134       

Регистры накопления. Структура хранения в базе данных 178

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Структура хранения регистров накопления в базе данных для платформы 1С:Предприятие 8.x. Первая часть в серии публикаций.

16.05.2019    21003    YPermitin    27       

Подборка решений для взаимодействия со ФГИС «Меркурий» Промо

С 1 июля 2019 года все компании, участвующие в обороте товаров животного происхождения, должны перейти на электронную ветеринарную сертификацию (ЭВС) через ФГИС «Меркурий». Инфостарт предлагает подборку программ, связанных с этим изменением.

Выполнение внешней обработки в фоновом задании 149

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Подробное описание подхода к созданию длительной операции на основе внешней обработки. Реализация протестирована на 1С 8.3.12.1714 (x64).

11.05.2019    12903    Eret1k    23       

Выгрузка документа по условию 5

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Разработка

Что делать, если документы нужно выгружать не все подряд, а по какому-то фильтру: статусу, дате, набору условий... А что если он соответствовал этим условиям, а потом перестал? А если потом опять начал? Такие ситуации заставили попотеть не одного программиста.

25.04.2019    7287    m-rv    2       

Программы для исполнения 54-ФЗ Промо

С 01.02.2017 контрольно-кассовая техника должна отправлять электронные версии чеков оператору фискальных данных - правила установлены в 54-ФЗ ст.2 п.2. Инфостарт предлагает подборку программ, связанных с применением 54-ФЗ, ККТ и электронных чеков.

Как прикрутить ГУИД к регистру сведений 23

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Перенос данных из 1C8 в 1C8 Разработка

... и немного теории обмена данными. В частности, разберем боль всех, кто пишет небанальные обмены данными: как набору записей регистра сведений назначить гуид и далее использовать его в обмене для идентификации этого набора.

16.04.2019    9858    m-rv    16       

О расширениях замолвите слово... 195

Статья Программист Стажер Нет файла v8 Бесплатно (free) Практика программирования Разработка

О чём стоит задуматься при принятии решения о создании расширения конфигурации…

07.04.2019    18857    ellavs    125       

Вакансия Автор новостных обзоров на тему 1С и бухучета, По совместительству Промо

Редакция Infostart.ru будет рада сотрудничеству с 1С-специалистом, умеющим и любящим излагать свои мысли в письменной форме. Если вы работали в IT-изданиях или имеете опыт ведения технологического блога/канала/группы, если сможете сделать обзор обработок из каталога infostart.ru/public/all/, то у вас большое преимущество.

Git-репозитории для 1С-кода (опыт использования при небольших проектах) 202

Статья Программист Стажер Нет файла v8 Windows Бесплатно (free) Практика программирования Разработка

Инструкции по взаимодействию с Git-репозиторием, которые писались для тех наших программистов, которые вообще никогда не работали с Git (руководства в духе "Как получить код из git-репозитория?", "Как отправить код в git-репозиторий")...

28.03.2019    15079    ellavs    83       

Трюки с внешними источниками данных 166

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Разработка

Некоторые трюки для преодоления ограничений внешних источников данных.

14.03.2019    15818    YPermitin    52       

1СПАРК РИСКИ. Сервис оценки благонадежности контрагентов. Промо

СПАРК помогает предотвратить мошенничество со стороны компаний и предпринимателей, благодаря актуальным сведениям о компаниях и системе выявления факторов риска.Сервис позволяет управлять налоговыми рисками и комплексно оценивать благонадежность контрагентов.

Возможности типовых шаблонов ограничения доступа на уровне записей (RLS) 173

Статья Программист Нет файла v8 v8::Права Бесплатно (free) Практика программирования БСП (Библиотека стандартных подсистем) Роли и права

Краткий обзор применения типовых шаблонов ограничения доступа на уровне записей в конфигурациях, созданных на базе БСП: #ПоЗначениям, #ПоНаборамЗначений, #ПоЗначениямРасширенный, #ПоЗначениямИНаборамРасширенный

03.02.2019    19092    ids79    9